REBOL [Title: "Upgrade"]

version: 1.3.1.3.1
url: http://www.rebol.com/downloads/view.exe

out: layout [
	vh2 "REBOL Update Available..."
	box 300x2 effect [gradient 255.0.0 80.0.0]
	text 300 bold "A newer version of REBOL is available. It is recommended that you update."
	space 0
	indent 24
	tt reform ["The new version is" version]
	tt reform ["You are using version" system/version]
	indent -24
	across
	pad 0x15
	button "Download" orange [
		file: request-file/only/file %view.exe
		if not file [exit]
		data: request-download url
		if not data [
			alert "NOTE: Download failed or was stopped by user."
			exit
		]
		if error? try [write/binary file data true][
			alert "NOTE: Cannot write output file."
			exit
		]
		unview/only out
		alert "Download complete. The new program has been downloaded. Run it to install (optional)."
	]
	button "Web Page" [
		browse http://www.rebol.com/view-platforms.html
	]
	button "Not Now" [unview/only out]
	return
]
out/effect: [gradient 0x1 180.200.180 120.140.120]
view/new center-face out
;do-events